Excel VBA の「オブジェクト活用」（Part.3）【データの並び替え・抽出編】

Sub filterObjectOpe()
'##################################################
'#  並び替え、抽出の操作                                                                                  #
'##################################################
'データベースの中で「並び替え」や「抽出」「検索」などに利用するデータ（基本的にはフィールド名に該当する列）のことをキーといいます。

'データの並び替え
'並び替えを行うときは「この表の」「この列（キー）」を「昇順か降順」で並び替えるといった手順になります。
'表のタイトルを除く場合はHeaderプロパティの設定をxlYesとします。
'---------------------------------------------------------------------------------------------
Worksheets("sheet7").Activate
Range("A1").Select
    With ActiveSheet.Sort
        'SortFields.Clearを利用して以前に使用した設定を解除します。
        .SortFields.Clear
        '下のプログラムで「この表の」を設定します。
        .SetRange Range("A1").CurrentRegion
        'Add2メソッドを利用して「キー」と「昇順か降順か」を設定します。
        '名前付き引数「Order」の定数「xlAscending」は昇順、「xlDescending」は降順。
        .SortFields.Add2 Key:=Range("D1"), Order:=xlDescending
        'HeaderプロパティをxlYesとして表のタイトルを並び替えの対象から外します。
        .Header = xlYes
        'Applyメソッドはこれまでの設定を利用して並び替えを行わせるメソッドです。
        .Apply
    End With
'---------------------------------------------------------------------------------------------

'データの抽出
'抽出を行うときは「この表の」「この列（キー）」で「設定条件に合う（もしくは合わない）」で抽出するといった手順になります。
'「AutoFilterの利用」
'---------------------------------------------------------------------------------------------
'現在のセレクション（セルA1かた連続したセル）の左から3列目の（C列）で「東京都●●」となっているデータを抽出
Selection.AutoFilter 3, "東京都*"
'引数を付けないでAutoFilterメソッドを利用するとフィルターを解除できます。
Selection.AutoFilter
'---------------------------------------------------------------------------------------------

Worksheets("Sheet6").Select
'セルの全ての設定（書式や値）のクリア
'---------------------------------------------------------------------------------------------
Range("A1:J50").Clear
'---------------------------------------------------------------------------------------------

Worksheets("Sheet7").Select
Range("C1").Select
'「AdvancedFilterの利用」
'Actionで抽出先を設定「xlFilterCopy」はCopyToRangeで指定した場所。「xlFilterInPlace」は現在の表を利用します。
'CriteriaRangeで検索条件の範囲を設定
'CopyToRangeでコピー先を設定
'---------------------------------------------------------------------------------------------
ActiveSheet.Columns("A:J").AdvancedFilter _
        Action:=xlFilterCopy, _
        CriteriaRange:=Worksheets("Sheet7").Range("L10:L11"), _
        CopyToRange:=Worksheets("Sheet6").Range("A2:J2")
'---------------------------------------------------------------------------------------------

'Worksheets("Sheet6").Select
'データの検索
'検索を行うときは「この表の」「この列（キー）」で「条件に合致するデータ」を探すといった手順になります。
'---------------------------------------------------------------------------------------------
Worksheets("Sheet6").Select
ActiveSheet.Range("A1").Value = "東京都"
Worksheets("Sheet7").Select

Dim tableRange As Range
Dim ObjectsTarget As Range
Dim StartRange As String

'検索の対象範囲をセットします。
Set tableRange = Range("A1").CurrentRegion

'「Findメソッド」の名前付き引数のWhatに検索する値を設定します。
'Lookatに「xlPart」を指定すると部分一致で検索し、「xlWhole」だと完全一致で検索を行います。
'検索対象のオブジェクトでFindメソッドを利用するためのオブジェクトを作成します｡
Set ObjectsTarget = tableRange.Find(What:=Worksheets("Sheet6").Range("A1").Value, Lookat:=xlPart)

'「Findメソッド」を利用
'ここでは「Findメソッド」の設定を入れたObjectsTargetを利用します。
'検索対象が見つかった場合（ObjectsTargetがNothingでないなら）
    If Not ObjectsTarget Is Nothing Then
    '得た情報のセルを選択します。
        ObjectsTarget.Select
    Else
        MsgBox ("検索対象は見つかりませんでした。")
    End If

'「FindNextメソッド」を利用
'「FindNextメソッド」は「Findメソッド」で開始した検索を続けて行うことができるメソッドです。
    If Not ObjectsTarget Is Nothing Then
    'ObjectsTargetのアドレスをStartRangeに格納します。
        StartRange = ObjectsTarget.Address
        Do
        MsgBox ObjectsTarget
        'FindNextメソッドの引数で検索中の現在のセルを指定して
        Set ObjectsTarget = tableRange.FindNext(ObjectsTarget)
        'ObjectsTargetのアドレスがStartRangeと再度同じになったら（検索が一周したら）終了します。
        Loop Until ObjectsTarget.Address = StartRange
    Else
        MsgBox ("検索対象は見つかりませんでした。")
    End If
'---------------------------------------------------------------------------------------------

'データの置き換え
'検索を行ったデータを別のデータとして書き換えるといった手順になります。
'---------------------------------------------------------------------------------------------
Range("A1").CurrentRegion.Replace What:="山本", Replacement:="山田", Lookat:=xlPart
'---------------------------------------------------------------------------------------------

End Sub